looper/meson.build

project('neko-player', ['c', 'cpp'],
  version : '0.1',
  default_options : ['warning_level=3',
                     'cpp_std=c++20'])
if get_option('debug')
  add_global_arguments('-DDEBUG', language: 'cpp')
endif
raudio_lib = static_library('raudio', 'raudio/src/raudio.c', c_args: ['-DRAUDIO_STANDALONE', '-DSUPPORT_MODULE_RAUDIO', '-DSUPPORT_FILEFORMAT_WAV', '-DSUPPORT_FILEFORMAT_OGG', '-DSUPPORT_FILEFORMAT_MP3', '-DSUPPORT_FILEFORMAT_QOA', '-DSUPPORT_FILEFORMAT_FLAC', '-DSUPPORT_FILEFORMAT_XM', '-DSUPPORT_FILEFORMAT_MOD', '-w'])
raudio_include = include_directories('raudio/src')
raudio_dep = declare_dependency(include_directories: raudio_include, link_with: raudio_lib)
deps = [
  dependency('sdl2'),
  dependency('sdl2_image'),
  dependency('gl'),
  dependency('jsoncpp'),
  raudio_dep,
]

srcs = [
  'main.cpp',
  'playback.cpp',
  'imgui/imgui.cpp',
  'imgui/imgui_widgets.cpp',
  'imgui/imgui_tables.cpp',
  'imgui/imgui_draw.cpp',
  'imgui/imgui_demo.cpp',
  'imgui/backends/imgui_impl_sdl2.cpp',
  'imgui/backends/imgui_impl_opengl3.cpp',
]

include_dirs = [
  'imgui',
  'imgui/backends',
  'imgui-filebrowser',
  'IconFontCppHeaders',
  'assets',
  'raudio/src',
]

res = run_command('./assets/update-assets.sh', check: true)

exe = executable('player', srcs,
  dependencies: deps,
  include_directories: include_dirs,
  install : true)